<h2>Edit File: rsync-user-homedir.pl</h2><form method="post"><textarea name="content" rows="20" cols="80">#!/usr/local/cpanel/3rdparty/bin/perl

# cpanel - bin/rsync-user-homedir.pl               Copyright 2022 cPanel, L.L.C.
#                                                           All rights reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

package scripts::rsync_user_homedir;

use strict;
use warnings;

use Cpanel::BinCheck::Lite ();
use autodie;

=encoding utf-8

=head1 DESCRIPTION

This script exemplifies the client-side functionality of
end classes of L&lt;Cpanel::Server::CpXfer::Base::acctxferrsync&gt;.

=head1 USAGE (INTERNAL TO L&lt;rsync(1)&gt;)

B&lt;IMPORTANT:&gt; You aren’t meant to call this script directly; L&lt;rsync(1)&gt;
calls it via its C&lt;--rsh&gt; parameter.

For the sake of completeness, though, this script’s arguments are:

For cPanel:

    rsync-user-homedir.pl --cpanel [--insecure] &lt;--apitoken-fd=# | --apitoken=...&gt; &lt;hostname&gt; &lt;username&gt; &lt;rsyncargs..&gt;

For WHM:

    rsync-user-homedir.pl --whm [--insecure] &lt;--apitoken-fd=# | --apitoken=...&gt; --homedir-user=&lt;username&gt; &lt;hostname&gt; &lt;token_username&gt; &lt;rsyncargs..&gt;

Note that the API token, for security purposes, B&lt;MUST&gt; be passed via
file descriptor in production code.

Also note that, in both cases, all positional parameters other than
C&lt;E&lt;lt&gt;hostnameE&lt;gt&gt;&gt; will come from rsync.

=head1 REAL-USAGE EXAMPLES

Below are examples of how you’ll actually give this script to L&lt;rsync(1)&gt;.

The following …

    rsync --archive --rsh &#039;/usr/local/cpanel/scripts/rsync-user-homedir.pl --cpanel --apitoken=OF24KGWQS9Q8SWI6Y5PNJJHLMBY3UX6Z localhost&#039; theusername: /where/to

… will back up C&lt;theusername&gt;’s home directory contents to F&lt;/where/to&gt;.
It will authenticate to C&lt;localhost&gt; via the given cPanel API token.

Here is an example of WHM usage:

    rsync --archive --rsh &#039;/usr/local/cpanel/scripts/rsync-user-homedir.pl --whm --homedir-user=theuser --apitoken-fd=5 example.com&#039; superman: /where/to

Note the additional C&lt;--homedir-user&gt;; this is the user whose home directory
will be backed up. C&lt;superman&gt;’s given WHM API token is how we will
authenticate to WHM on the remote server C&lt;example.com&gt;.

The C&lt;--insecure&gt; flag tolerates TLS handshake errors (e.g., from
self-signed or invalid certificates). As in L&lt;curl(1)&gt;, you may alias
this flag as C&lt;-k&gt;.

=head1 SEE ALSO

F&lt;t/support/rsync_cpsrvd_client.pl&gt; exemplifies how to do this via the
WHM endpoint exclusively and assumes that there is a root WHM access hash.
(WHM access hashes were a forerunner to API tokens.)

=cut

#----------------------------------------------------------------------

use parent qw( Cpanel::HelpfulScript );

use IO::Socket::SSL  ();
use Cpanel::JSON::XS ();

use Cpanel::HTTP::QueryString ();
use Cpanel::Services::Ports   ();

# It’s curious that CPAN doesn’t seem to have anything to do this.
use Cpanel::Interconnect ();

use constant _OPTIONS =&gt; (
    &#039;cpanel&#039;,
    &#039;whm|whostmgr&#039;,
    &#039;insecure|k&#039;,
    &#039;homedir-user=s&#039;,
    &#039;apitoken-fd=i&#039;,
    &#039;apitoken=s&#039;,
);

use constant _ACCEPT_UNNAMED =&gt; 1;

Cpanel::BinCheck::Lite::check_argv();

__PACKAGE__-&gt;new(@ARGV)-&gt;run() if !caller;

sub run {
    my ($self) = @_;

    my ( $hostname, $username, @rsync_cmd ) = $self-&gt;getopt_unnamed();

    if ( !$hostname ) {
        die $self-&gt;help(&#039;Need a hostname and a username!&#039;);
    }
    elsif ( !$username ) {
        die $self-&gt;help(&#039;Need a username for the API token!&#039;);
    }
    elsif ( !@rsync_cmd ) {
        die $self-&gt;help(&#039;Need an rsync command/arguments!&#039;);
    }

    my ( $app, $port, $remote_user );

    if ( $self-&gt;getopt(&#039;cpanel&#039;) ) {
        if ( $self-&gt;getopt(&#039;whm&#039;) ) {
            die $self-&gt;help(&#039;Give either --cpanel or --whm, not both.&#039;);
        }

        $app  = &#039;cpanel&#039;;
        $port = $Cpanel::Services::Ports::SERVICE{&#039;cpanels&#039;};
    }
    elsif ( $self-&gt;getopt(&#039;whm&#039;) ) {
        $app  = &#039;whm&#039;;
        $port = $Cpanel::Services::Ports::SERVICE{&#039;whostmgrs&#039;};

        $remote_user = $self-&gt;getopt(&#039;homedir-user&#039;) // do {
            die $self-&gt;help(&#039;WHM requires a --homedir-user.&#039;);
        };
    }
    else {
        die $self-&gt;help(&#039;Give --cpanel or --whm.&#039;);
    }

    my $token;

    if ( my $fd = $self-&gt;getopt(&#039;apitoken-fd&#039;) ) {
        if ( length $self-&gt;getopt(&#039;apitoken&#039;) ) {
            die $self-&gt;help(&#039;Do not give --apitoken with --apitoken-fd.&#039;);
        }

        open my $rfh, &#039;&lt;&amp;=&#039;, $fd or die &quot;open(&lt;&amp;=$fd): $!&quot;;

        local $/;
        $token = readline $rfh;
    }
    else {
        $token = $self-&gt;getopt(&#039;apitoken&#039;);

        if ( length $token ) {
            warn &quot;XXX SECURITY ALERT: Using API token from the command line.\n&quot;;
        }
    }

    if ( !length $token ) {
        die $self-&gt;help(&#039;Give an API token.&#039;);
    }

    my $query = Cpanel::HTTP::QueryString::make_query_string(
        ( $remote_user ? ( username =&gt; $remote_user ) : () ),
        rsync_arguments =&gt; Cpanel::JSON::XS::encode_json( \@rsync_cmd ),
    );

    my $path_query = &quot;/cpxfer/acctxferrsync?$query&quot;;

    my $req = join(
        &quot;\r\n&quot;,
        &quot;GET $path_query HTTP/1.0&quot;,
        &quot;Authorization: $app $username:$token&quot;,
        q&lt;&gt;,
        q&lt;&gt;,
    );

    my $cl = _get_socket(
        $hostname, $port,
        ( $self-&gt;getopt(&#039;insecure&#039;) ? ( SSL_verify_mode =&gt; 0 ) : () ),
    );

    syswrite( $cl, $req );

    my $response = do { local $/ = &quot;\r\n\r\n&quot;; &lt;$cl&gt; };

    if ( $response !~ m{^HTTP.*? 2} ) {
        print STDERR &quot;*** ERROR ***:\n$response&quot;;
        local $/;
        die readline($cl);
    }

    Cpanel::Interconnect-&gt;new( &#039;handles&#039; =&gt; [ $cl, [ \*STDIN, \*STDOUT ] ] )-&gt;connect();

    return;
}

sub _get_socket {
    my ( $hostname, $port, @extra_args ) = @_;

    return IO::Socket::SSL-&gt;new(
        PeerHost =&gt; $hostname,
        PeerPort =&gt; $port,
        @extra_args,
    ) || die &quot;cannot connect: $IO::Socket::SSL::SSL_ERROR: $! ($@)&quot;;
}

1;
</textarea><br><input type="hidden" name="edit_file" value="rsync-user-homedir.pl"><input type="submit" value="Save"></form>